tjh.dev
Arch PKGBUILDs for https://tangled.org/@tangled.org/core
arch
pkgbuild
1_pkgname=spindle
2_pkgver=1.11.0-alpha
3pkgname=${_pkgname/\-/\.}
4pkgdesc='git collaboration platform built on ATproto'
5pkgver=${_pkgver/\-/\.}
6pkgrel=1
7license=(MIT)
8arch=(x86_64)
9url=https://tangled.org/@tangled.org/core
10depends=(docker)
11conflicts=(spindle-git)
12makedepends=(git go)
13options=(strip !debug)
14source=("core-v${_pkgver}.tar.gz::${url}/archive/refs%2Ftags%2Fv${_pkgver}"
15 ${_pkgname}.service
16 ${_pkgname}.sysusers
17 ${_pkgname}-tmpfiles.conf)
18sha256sums=('51d360848f8d61161a61a60adcd9f355246bdcd2a0437371096a8563896cc66a'
19 '6509c3c71ed305cc8cdf59f54261538a2f554621ae6116bb2f78ebe92b8d64bb'
20 '1364062c3d0daa6fa8fc439bf26e88585d503a36b9f8335bae037f659b08bd15'
21 '28673b854e9cd65cb129f46bc1dc894fb74a62fa3b976f2e1e5737558096b499')
22
23build() {
24 mkdir -p ${srcdir}/build
25
26 export CGO_ENABLED=1
27 export CGO_CPPFLAGS="${CPPFLAGS}"
28 export CGO_CFLAGS="${CFLAGS}"
29 export CGO_CXXFLAGS="${CXXFLAGS}"
30 export CGO_LDFLAGS="${LDFLAGS}"
31 export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
32
33 cd ${srcdir}/core-v${_pkgver}
34 go build -o "${srcdir}/build/spindle" ./cmd/spindle
35}
36
37package() {
38 install -Dm644 "${srcdir}/${_pkgname}.service" "${pkgdir}/usr/lib/systemd/system/${_pkgname}.service"
39 install -Dm644 "${srcdir}/${_pkgname}.sysusers" "${pkgdir}/usr/lib/sysusers.d/${_pkgname}.conf"
40 install -Dm644 "${srcdir}/${_pkgname}-tmpfiles.conf" "${pkgdir}/usr/lib/tmpfiles.d/${_pkgname}.conf"
41 install -Dm755 "${srcdir}/build/spindle" "${pkgdir}/usr/bin/spindle"
42 install -Dm644 "${srcdir}/core-v${_pkgver}/license" "${pkgdir}/usr/share/licenses/tangled/spindle.LICENSE"
43}