tangled.org
Monorepo for Tangled
tangled.org
anirudh.fi
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 fenix = {
7 url = "github:nix-community/fenix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 gomod2nix = {
11 url = "github:nix-community/gomod2nix";
12 inputs.nixpkgs.follows = "nixpkgs";
13 };
14 flake-compat = {
15 url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
16 flake = false;
17 };
18 indigo = {
19 url = "github:oppiliappan/indigo";
20 flake = false;
21 };
22 htmx-src = {
23 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
24 flake = false;
25 };
26 htmx-ws-src = {
27 # strange errors in consle that i can't really make out
28 # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
29 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
30 flake = false;
31 };
32 lucide-src = {
33 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
34 flake = false;
35 };
36 inter-fonts-src = {
37 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
38 flake = false;
39 };
40 actor-typeahead-src = {
41 url = "git+https://tangled.org/@jakelazaroff.com/actor-typeahead";
42 flake = false;
43 };
44 mermaid-src = {
45 url = "https://cdn.jsdelivr.net/npm/mermaid@11.12.3/dist/mermaid.min.js";
46 flake = false;
47 };
48 ibm-plex-mono-src = {
49 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
50 flake = false;
51 };
52 sqlite-lib-src = {
53 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
54 flake = false;
55 };
56 };
57
58 outputs = {
59 self,
60 nixpkgs,
61 fenix,
62 gomod2nix,
63 indigo,
64 htmx-src,
65 htmx-ws-src,
66 lucide-src,
67 inter-fonts-src,
68 sqlite-lib-src,
69 ibm-plex-mono-src,
70 actor-typeahead-src,
71 mermaid-src,
72 ...
73 }: let
74 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
75 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
76 nixpkgsFor = forAllSystems (system: nixpkgs.legacyPackages.${system});
77
78 mkPackageSet = pkgs:
79 pkgs.lib.makeScope pkgs.newScope (self: {
80 src = let
81 fs = pkgs.lib.fileset;
82 in
83 fs.toSource {
84 root = ./.;
85 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
86 };
87 buildGoApplication =
88 (self.callPackage "${gomod2nix}/builder" {
89 gomod2nix = gomod2nix.legacyPackages.${pkgs.stdenv.hostPlatform.system}.gomod2nix;
90 }).buildGoApplication;
91 modules = ./nix/gomod2nix.toml;
92 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
93 inherit sqlite-lib-src;
94 };
95 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
96 goat = self.callPackage ./nix/pkgs/goat.nix {inherit indigo;};
97 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
98 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src actor-typeahead-src mermaid-src;
99 };
100 appview = self.callPackage ./nix/pkgs/appview.nix {};
101 docs = self.callPackage ./nix/pkgs/docs.nix {
102 inherit inter-fonts-src ibm-plex-mono-src lucide-src;
103 };
104 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
105 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
106 knot = self.callPackage ./nix/pkgs/knot.nix {};
107 dolly = self.callPackage ./nix/pkgs/dolly.nix {};
108 });
109 in {
110 overlays.default = final: prev: {
111 inherit (mkPackageSet final) lexgen goat sqlite-lib spindle knot-unwrapped knot appview docs dolly;
112 };
113
114 packages = forAllSystems (system: let
115 pkgs = nixpkgsFor.${system};
116 packages = mkPackageSet pkgs;
117 staticPackages = mkPackageSet pkgs.pkgsStatic;
118 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
119 in {
120 inherit
121 (packages)
122 appview
123 appview-static-files
124 lexgen
125 goat
126 spindle
127 knot
128 knot-unwrapped
129 sqlite-lib
130 docs
131 dolly
132 ;
133
134 pkgsStatic-appview = staticPackages.appview;
135 pkgsStatic-knot = staticPackages.knot;
136 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
137 pkgsStatic-spindle = staticPackages.spindle;
138 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
139 pkgsStatic-dolly = staticPackages.dolly;
140
141 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
142 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
143 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
144 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
145 pkgsCross-gnu64-pkgsStatic-dolly = crossPackages.dolly;
146
147 treefmt-wrapper = pkgs.treefmt.withConfig {
148 settings.formatter = {
149 alejandra = {
150 command = pkgs.lib.getExe pkgs.alejandra;
151 includes = ["*.nix"];
152 };
153
154 gofmt = {
155 command = pkgs.lib.getExe' pkgs.go "gofmt";
156 options = ["-w"];
157 includes = ["*.go"];
158 };
159
160 # prettier = let
161 # wrapper = pkgs.runCommandLocal "prettier-wrapper" {nativeBuildInputs = [pkgs.makeWrapper];} ''
162 # makeWrapper ${pkgs.prettier}/bin/prettier "$out" --add-flags "--plugin=${pkgs.prettier-plugin-go-template}/lib/node_modules/prettier-plugin-go-template/lib/index.js"
163 # '';
164 # in {
165 # command = wrapper;
166 # options = ["-w"];
167 # includes = ["*.html"];
168 # # causes Go template plugin errors: https://github.com/NiklasPor/prettier-plugin-go-template/issues/120
169 # excludes = ["appview/pages/templates/layouts/repobase.html" "appview/pages/templates/repo/tags.html"];
170 # };
171 };
172 };
173 });
174 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
175 devShells = forAllSystems (system: let
176 pkgs = nixpkgsFor.${system};
177 packages' = self.packages.${system};
178 staticShell = pkgs.mkShell.override {
179 stdenv = pkgs.pkgsStatic.stdenv;
180 };
181 in {
182 default = staticShell {
183 nativeBuildInputs = [
184 pkgs.go
185 pkgs.air
186 pkgs.gopls
187 pkgs.httpie
188 pkgs.litecli
189 pkgs.websocat
190 pkgs.tailwindcss
191 pkgs.nixos-shell
192 pkgs.redis
193 pkgs.worker-build
194 pkgs.cargo-generate
195 (fenix.packages.${system}.combine [
196 fenix.packages.${system}.stable.cargo
197 fenix.packages.${system}.stable.rustc
198 fenix.packages.${system}.stable.rust-src
199 fenix.packages.${system}.stable.clippy
200 fenix.packages.${system}.stable.rustfmt
201 fenix.packages.${system}.targets.wasm32-unknown-unknown.stable.rust-std
202 ])
203 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
204 packages'.lexgen
205 packages'.treefmt-wrapper
206 ];
207 shellHook = ''
208 mkdir -p appview/pages/static
209 # no preserve is needed because watch-tailwind will want to be able to overwrite
210 cp -fr --no-preserve=ownership ${packages'.appview-static-files}/* appview/pages/static
211
212 export TANGLED_OAUTH_CLIENT_KID="$(date +%s)"
213 export TANGLED_OAUTH_CLIENT_SECRET="$(${packages'.goat}/bin/goat key generate -t P-256 | grep -A1 "Secret Key" | tail -n1 | awk '{print $1}')"
214 '';
215 env.CGO_ENABLED = 1;
216 };
217 });
218 apps = forAllSystems (system: let
219 pkgs = nixpkgsFor."${system}";
220 packages' = self.packages.${system};
221 air-watcher = name: arg:
222 pkgs.writeShellScriptBin "run"
223 ''
224 export PATH=${pkgs.go}/bin:$PATH
225 ${pkgs.air}/bin/air -c ./.air/${name}.toml \
226 -build.args_bin "${arg}"
227 '';
228 tailwind-watcher =
229 pkgs.writeShellScriptBin "run"
230 ''
231 ${pkgs.tailwindcss}/bin/tailwindcss --watch=always -i input.css -o ./appview/pages/static/tw.css
232 '';
233 in {
234 fmt = {
235 type = "app";
236 program = pkgs.lib.getExe packages'.treefmt-wrapper;
237 };
238 watch-appview = {
239 type = "app";
240 program = toString (pkgs.writeShellScript "watch-appview" ''
241 echo "copying static files to appview/pages/static..."
242 mkdir -p appview/pages/static
243 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership ${packages'.appview-static-files}/* appview/pages/static
244 ${air-watcher "appview" ""}/bin/run
245 '');
246 };
247 watch-knot = {
248 type = "app";
249 program = ''${air-watcher "knot" "server"}/bin/run'';
250 };
251 watch-spindle = {
252 type = "app";
253 program = ''${air-watcher "spindle" ""}/bin/run'';
254 };
255 watch-tailwind = {
256 type = "app";
257 program = ''${tailwind-watcher}/bin/run'';
258 };
259 vm = let
260 guestSystem =
261 if pkgs.stdenv.hostPlatform.isAarch64
262 then "aarch64-linux"
263 else "x86_64-linux";
264 in {
265 type = "app";
266 program =
267 (pkgs.writeShellApplication {
268 name = "launch-vm";
269 text = ''
270 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
271 cd "$rootDir"
272
273 mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
274
275 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
276 exec ${pkgs.lib.getExe
277 (import ./nix/vm.nix {
278 inherit nixpkgs self;
279 system = guestSystem;
280 hostSystem = system;
281 }).config.system.build.vm}
282 '';
283 })
284 + /bin/launch-vm;
285 };
286 gomod2nix = {
287 type = "app";
288 program = toString (pkgs.writeShellScript "gomod2nix" ''
289 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
290 '');
291 };
292 lexgen = {
293 type = "app";
294 program =
295 (pkgs.writeShellApplication {
296 name = "lexgen";
297 text = ''
298 if ! command -v lexgen > /dev/null; then
299 echo "error: must be executed from devshell"
300 exit 1
301 fi
302
303 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
304 cd "$rootDir"
305
306 rm -f api/tangled/*
307 lexgen --build-file lexicon-build-config.json lexicons
308 sed -i.bak 's/\tutil/\/\/\tutil/' api/tangled/*
309 # lexgen generates incomplete Marshaler/Unmarshaler for union types
310 find api/tangled/*.go -not -name "cbor_gen.go" -exec \
311 sed -i '/^func.*\(MarshalCBOR\|UnmarshalCBOR\)/,/^}/ s/^/\/\/ /' {} +
312 ${pkgs.gotools}/bin/goimports -w api/tangled/*
313 go run ./cmd/cborgen/
314 lexgen --build-file lexicon-build-config.json lexicons
315 rm api/tangled/*.bak
316 '';
317 })
318 + /bin/lexgen;
319 };
320 });
321
322 nixosModules.appview = {
323 lib,
324 pkgs,
325 ...
326 }: {
327 imports = [./nix/modules/appview.nix];
328
329 services.tangled.appview.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.appview;
330 };
331 nixosModules.knot = {
332 lib,
333 pkgs,
334 ...
335 }: {
336 imports = [./nix/modules/knot.nix];
337
338 services.tangled.knot.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot;
339 };
340 nixosModules.spindle = {
341 lib,
342 pkgs,
343 ...
344 }: {
345 imports = [./nix/modules/spindle.nix];
346
347 services.tangled.spindle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.spindle;
348 };
349 };
350}