marco.tngl.sh
forked from
tangled.org/core
Monorepo for Tangled
boltless.me
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 gomod2nix = {
7 url = "github:nix-community/gomod2nix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 flake-compat = {
11 url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
12 flake = false;
13 };
14 indigo = {
15 url = "github:oppiliappan/indigo";
16 flake = false;
17 };
18 htmx-src = {
19 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
20 flake = false;
21 };
22 htmx-ws-src = {
23 # strange errors in consle that i can't really make out
24 # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
25 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
26 flake = false;
27 };
28 lucide-src = {
29 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
30 flake = false;
31 };
32 inter-fonts-src = {
33 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
34 flake = false;
35 };
36 actor-typeahead-src = {
37 url = "git+https://tangled.org/@jakelazaroff.com/actor-typeahead";
38 flake = false;
39 };
40 ibm-plex-mono-src = {
41 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
42 flake = false;
43 };
44 sqlite-lib-src = {
45 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
46 flake = false;
47 };
48 };
49
50 outputs = {
51 self,
52 nixpkgs,
53 gomod2nix,
54 indigo,
55 htmx-src,
56 htmx-ws-src,
57 lucide-src,
58 inter-fonts-src,
59 sqlite-lib-src,
60 ibm-plex-mono-src,
61 actor-typeahead-src,
62 ...
63 }: let
64 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
65 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
66 nixpkgsFor = forAllSystems (system: nixpkgs.legacyPackages.${system});
67
68 mkPackageSet = pkgs:
69 pkgs.lib.makeScope pkgs.newScope (self: {
70 src = let
71 fs = pkgs.lib.fileset;
72 in
73 fs.toSource {
74 root = ./.;
75 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
76 };
77 buildGoApplication =
78 (self.callPackage "${gomod2nix}/builder" {
79 gomod2nix = gomod2nix.legacyPackages.${pkgs.stdenv.hostPlatform.system}.gomod2nix;
80 }).buildGoApplication;
81 modules = ./nix/gomod2nix.toml;
82 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
83 inherit sqlite-lib-src;
84 };
85 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
86 goat = self.callPackage ./nix/pkgs/goat.nix {inherit indigo;};
87 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
88 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src actor-typeahead-src;
89 };
90 appview = self.callPackage ./nix/pkgs/appview.nix {};
91 docs = self.callPackage ./nix/pkgs/docs.nix {
92 inherit inter-fonts-src ibm-plex-mono-src lucide-src;
93 };
94 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
95 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
96 knot = self.callPackage ./nix/pkgs/knot.nix {};
97 dolly = self.callPackage ./nix/pkgs/dolly.nix {};
98 did-method-plc = self.callPackage ./nix/pkgs/did-method-plc.nix {};
99 bluesky-jetstream = self.callPackage ./nix/pkgs/bluesky-jetstream.nix {};
100 bluesky-relay = self.callPackage ./nix/pkgs/bluesky-relay.nix {};
101 tap = self.callPackage ./nix/pkgs/tap.nix {};
102 knotmirror = self.callPackage ./nix/pkgs/knot-mirror.nix {};
103 });
104 in {
105 overlays.default = final: prev: {
106 inherit (mkPackageSet final) lexgen goat sqlite-lib spindle knot-unwrapped knot appview docs dolly did-method-plc bluesky-jetstream bluesky-relay tap knotmirror;
107 };
108
109 packages = forAllSystems (system: let
110 pkgs = nixpkgsFor.${system};
111 packages = mkPackageSet pkgs;
112 staticPackages = mkPackageSet pkgs.pkgsStatic;
113 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
114 in {
115 inherit
116 (packages)
117 appview
118 appview-static-files
119 lexgen
120 goat
121 spindle
122 knot
123 knot-unwrapped
124 sqlite-lib
125 docs
126 dolly
127 did-method-plc
128 bluesky-jetstream
129 bluesky-relay
130 tap
131 ;
132
133 pkgsStatic-appview = staticPackages.appview;
134 pkgsStatic-knot = staticPackages.knot;
135 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
136 pkgsStatic-spindle = staticPackages.spindle;
137 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
138 pkgsStatic-dolly = staticPackages.dolly;
139
140 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
141 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
142 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
143 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
144 pkgsCross-gnu64-pkgsStatic-dolly = crossPackages.dolly;
145
146 treefmt-wrapper = pkgs.treefmt.withConfig {
147 settings.formatter = {
148 alejandra = {
149 command = pkgs.lib.getExe pkgs.alejandra;
150 includes = ["*.nix"];
151 };
152
153 gofmt = {
154 command = pkgs.lib.getExe' pkgs.go "gofmt";
155 options = ["-w"];
156 includes = ["*.go"];
157 };
158
159 # prettier = let
160 # wrapper = pkgs.runCommandLocal "prettier-wrapper" {nativeBuildInputs = [pkgs.makeWrapper];} ''
161 # makeWrapper ${pkgs.prettier}/bin/prettier "$out" --add-flags "--plugin=${pkgs.prettier-plugin-go-template}/lib/node_modules/prettier-plugin-go-template/lib/index.js"
162 # '';
163 # in {
164 # command = wrapper;
165 # options = ["-w"];
166 # includes = ["*.html"];
167 # # causes Go template plugin errors: https://github.com/NiklasPor/prettier-plugin-go-template/issues/120
168 # excludes = ["appview/pages/templates/layouts/repobase.html" "appview/pages/templates/repo/tags.html"];
169 # };
170 };
171 };
172 });
173 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
174 devShells = forAllSystems (system: let
175 pkgs = nixpkgsFor.${system};
176 packages' = self.packages.${system};
177 staticShell = pkgs.mkShell.override {
178 stdenv = pkgs.pkgsStatic.stdenv;
179 };
180 in {
181 default = staticShell {
182 nativeBuildInputs = [
183 pkgs.go
184 pkgs.air
185 pkgs.gopls
186 pkgs.httpie
187 pkgs.litecli
188 pkgs.websocat
189 pkgs.tailwindcss
190 pkgs.nixos-shell
191 pkgs.redis
192 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
193 packages'.lexgen
194 packages'.treefmt-wrapper
195 packages'.tap
196 ];
197 shellHook = ''
198 mkdir -p appview/pages/static
199 # no preserve is needed because watch-tailwind will want to be able to overwrite
200 cp -fr --no-preserve=ownership ${packages'.appview-static-files}/* appview/pages/static
201 export TANGLED_OAUTH_CLIENT_KID="$(date +%s)"
202 export TANGLED_OAUTH_CLIENT_SECRET="$(${packages'.goat}/bin/goat key generate -t P-256 | grep -A1 "Secret Key" | tail -n1 | awk '{print $1}')"
203 '';
204 env.CGO_ENABLED = 1;
205 };
206 });
207 apps = forAllSystems (system: let
208 pkgs = nixpkgsFor."${system}";
209 packages' = self.packages.${system};
210 air-watcher = name: arg:
211 pkgs.writeShellScriptBin "run"
212 ''
213 export PATH=${pkgs.go}/bin:$PATH
214 ${pkgs.air}/bin/air -c ./.air/${name}.toml \
215 -build.args_bin "${arg}"
216 '';
217 tailwind-watcher =
218 pkgs.writeShellScriptBin "run"
219 ''
220 ${pkgs.tailwindcss}/bin/tailwindcss --watch=always -i input.css -o ./appview/pages/static/tw.css
221 '';
222 in {
223 fmt = {
224 type = "app";
225 program = pkgs.lib.getExe packages'.treefmt-wrapper;
226 };
227 watch-appview = {
228 type = "app";
229 program = toString (pkgs.writeShellScript "watch-appview" ''
230 echo "copying static files to appview/pages/static..."
231 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership ${packages'.appview-static-files}/* appview/pages/static
232 ${air-watcher "appview" ""}/bin/run
233 '');
234 };
235 watch-knot = {
236 type = "app";
237 program = ''${air-watcher "knot" "server"}/bin/run'';
238 };
239 watch-spindle = {
240 type = "app";
241 program = ''${air-watcher "spindle" ""}/bin/run'';
242 };
243 watch-tailwind = {
244 type = "app";
245 program = ''${tailwind-watcher}/bin/run'';
246 };
247 vm = let
248 guestSystem =
249 if pkgs.stdenv.hostPlatform.isAarch64
250 then "aarch64-linux"
251 else "x86_64-linux";
252 in {
253 type = "app";
254 program =
255 (pkgs.writeShellApplication {
256 name = "launch-vm";
257 text = ''
258 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
259 cd "$rootDir"
260
261 mkdir -p nix/vm-data/{caddy,knot,repos,spindle,spindle-logs}
262
263 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
264 exec ${pkgs.lib.getExe
265 (import ./nix/vm.nix {
266 inherit nixpkgs self;
267 system = guestSystem;
268 hostSystem = system;
269 }).config.system.build.vm}
270 '';
271 })
272 + /bin/launch-vm;
273 };
274 gomod2nix = {
275 type = "app";
276 program = toString (pkgs.writeShellScript "gomod2nix" ''
277 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
278 '');
279 };
280 lexgen = {
281 type = "app";
282 program =
283 (pkgs.writeShellApplication {
284 name = "lexgen";
285 text = ''
286 if ! command -v lexgen > /dev/null; then
287 echo "error: must be executed from devshell"
288 exit 1
289 fi
290
291 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
292 cd "$rootDir"
293
294 rm -f api/tangled/*
295 lexgen --build-file lexicon-build-config.json lexicons
296 sed -i.bak 's/\tutil/\/\/\tutil/' api/tangled/*
297 # lexgen generates incomplete Marshaler/Unmarshaler for union types
298 find api/tangled/*.go -not -name "cbor_gen.go" -exec \
299 sed -i '/^func.*\(MarshalCBOR\|UnmarshalCBOR\)/,/^}/ s/^/\/\/ /' {} +
300 ${pkgs.gotools}/bin/goimports -w api/tangled/*
301 go run ./cmd/cborgen/
302 lexgen --build-file lexicon-build-config.json lexicons
303 rm api/tangled/*.bak
304 '';
305 })
306 + /bin/lexgen;
307 };
308 });
309
310 nixosModules.appview = {
311 lib,
312 pkgs,
313 ...
314 }: {
315 imports = [./nix/modules/appview.nix];
316
317 services.tangled.appview.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.appview;
318 };
319 nixosModules.knot = {
320 lib,
321 pkgs,
322 ...
323 }: {
324 imports = [./nix/modules/knot.nix];
325
326 services.tangled.knot.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot;
327 };
328 nixosModules.spindle = {
329 lib,
330 pkgs,
331 ...
332 }: {
333 imports = [./nix/modules/spindle.nix];
334
335 services.tangled.spindle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.spindle;
336 services.tangled.spindle.tap-package = lib.mkDefault self.packages.${pkgs.system}.tap;
337 };
338 nixosModules.did-method-plc = {
339 lib,
340 pkgs,
341 ...
342 }: {
343 imports = [./nix/modules/did-method-plc.nix];
344 services.did-method-plc.package = lib.mkDefault self.packages.${pkgs.system}.did-method-plc;
345 };
346 nixosModules.bluesky-relay = {
347 lib,
348 pkgs,
349 ...
350 }: {
351 imports = [./nix/modules/bluesky-relay.nix];
352 services.bluesky-relay.package = lib.mkDefault self.packages.${pkgs.system}.bluesky-relay;
353 };
354 nixosModules.bluesky-jetstream = {
355 lib,
356 pkgs,
357 ...
358 }: {
359 imports = [./nix/modules/bluesky-jetstream.nix];
360 services.bluesky-jetstream.package = lib.mkDefault self.packages.${pkgs.system}.bluesky-jetstream;
361 };
362 };
363}