lewis.moe
Monorepo for Tangled
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 gomod2nix = {
7 url = "github:nix-community/gomod2nix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 flake-compat = {
11 url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
12 flake = false;
13 };
14 indigo = {
15 url = "github:oppiliappan/indigo";
16 flake = false;
17 };
18 htmx-src = {
19 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
20 flake = false;
21 };
22 htmx-ws-src = {
23 # strange errors in consle that i can't really make out
24 # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
25 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
26 flake = false;
27 };
28 lucide-src = {
29 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
30 flake = false;
31 };
32 inter-fonts-src = {
33 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
34 flake = false;
35 };
36 actor-typeahead-src = {
37 url = "git+https://tangled.org/@jakelazaroff.com/actor-typeahead";
38 flake = false;
39 };
40 mermaid-src = {
41 url = "https://cdn.jsdelivr.net/npm/mermaid@11.12.3/dist/mermaid.min.js";
42 flake = false;
43 };
44 ibm-plex-mono-src = {
45 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
46 flake = false;
47 };
48 sqlite-lib-src = {
49 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
50 flake = false;
51 };
52 };
53
54 outputs = {
55 self,
56 nixpkgs,
57 gomod2nix,
58 indigo,
59 htmx-src,
60 htmx-ws-src,
61 lucide-src,
62 inter-fonts-src,
63 sqlite-lib-src,
64 ibm-plex-mono-src,
65 actor-typeahead-src,
66 mermaid-src,
67 ...
68 }: let
69 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
70 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
71 nixpkgsFor = forAllSystems (system: nixpkgs.legacyPackages.${system});
72
73 mkPackageSet = pkgs:
74 pkgs.lib.makeScope pkgs.newScope (self: {
75 src = let
76 fs = pkgs.lib.fileset;
77 in
78 fs.toSource {
79 root = ./.;
80 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
81 };
82 buildGoApplication =
83 (self.callPackage "${gomod2nix}/builder" {
84 gomod2nix = gomod2nix.legacyPackages.${pkgs.stdenv.hostPlatform.system}.gomod2nix;
85 }).buildGoApplication;
86 modules = ./nix/gomod2nix.toml;
87 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
88 inherit sqlite-lib-src;
89 };
90 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
91 goat = self.callPackage ./nix/pkgs/goat.nix {inherit indigo;};
92 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
93 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src actor-typeahead-src mermaid-src;
94 };
95 appview = self.callPackage ./nix/pkgs/appview.nix {};
96 docs = self.callPackage ./nix/pkgs/docs.nix {
97 inherit inter-fonts-src ibm-plex-mono-src lucide-src;
98 };
99 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
100 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
101 knot = self.callPackage ./nix/pkgs/knot.nix {};
102 dolly = self.callPackage ./nix/pkgs/dolly.nix {};
103 });
104 in {
105 overlays.default = final: prev: {
106 inherit (mkPackageSet final) lexgen goat sqlite-lib spindle knot-unwrapped knot appview docs dolly;
107 };
108
109 packages = forAllSystems (system: let
110 pkgs = nixpkgsFor.${system};
111 packages = mkPackageSet pkgs;
112 staticPackages = mkPackageSet pkgs.pkgsStatic;
113 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
114 in {
115 inherit
116 (packages)
117 appview
118 appview-static-files
119 lexgen
120 goat
121 spindle
122 knot
123 knot-unwrapped
124 sqlite-lib
125 docs
126 dolly
127 ;
128
129 pkgsStatic-appview = staticPackages.appview;
130 pkgsStatic-knot = staticPackages.knot;
131 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
132 pkgsStatic-spindle = staticPackages.spindle;
133 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
134 pkgsStatic-dolly = staticPackages.dolly;
135
136 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
137 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
138 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
139 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
140 pkgsCross-gnu64-pkgsStatic-dolly = crossPackages.dolly;
141
142 treefmt-wrapper = pkgs.treefmt.withConfig {
143 settings.formatter = {
144 alejandra = {
145 command = pkgs.lib.getExe pkgs.alejandra;
146 includes = ["*.nix"];
147 };
148
149 gofmt = {
150 command = pkgs.lib.getExe' pkgs.go "gofmt";
151 options = ["-w"];
152 includes = ["*.go"];
153 };
154
155 # prettier = let
156 # wrapper = pkgs.runCommandLocal "prettier-wrapper" {nativeBuildInputs = [pkgs.makeWrapper];} ''
157 # makeWrapper ${pkgs.prettier}/bin/prettier "$out" --add-flags "--plugin=${pkgs.prettier-plugin-go-template}/lib/node_modules/prettier-plugin-go-template/lib/index.js"
158 # '';
159 # in {
160 # command = wrapper;
161 # options = ["-w"];
162 # includes = ["*.html"];
163 # # causes Go template plugin errors: https://github.com/NiklasPor/prettier-plugin-go-template/issues/120
164 # excludes = ["appview/pages/templates/layouts/repobase.html" "appview/pages/templates/repo/tags.html"];
165 # };
166 };
167 };
168 });
169 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
170 devShells = forAllSystems (system: let
171 pkgs = nixpkgsFor.${system};
172 packages' = self.packages.${system};
173 staticShell = pkgs.mkShell.override {
174 stdenv = pkgs.pkgsStatic.stdenv;
175 };
176 in {
177 default = staticShell {
178 nativeBuildInputs = [
179 pkgs.go
180 pkgs.air
181 pkgs.gopls
182 pkgs.httpie
183 pkgs.litecli
184 pkgs.websocat
185 pkgs.tailwindcss
186 pkgs.nixos-shell
187 pkgs.redis
188 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
189 packages'.lexgen
190 packages'.treefmt-wrapper
191 ];
192 shellHook = ''
193 mkdir -p appview/pages/static
194 # no preserve is needed because watch-tailwind will want to be able to overwrite
195 cp -fr --no-preserve=ownership ${packages'.appview-static-files}/* appview/pages/static
196 export TANGLED_OAUTH_CLIENT_KID="$(date +%s)"
197 export TANGLED_OAUTH_CLIENT_SECRET="$(${packages'.goat}/bin/goat key generate -t P-256 | grep -A1 "Secret Key" | tail -n1 | awk '{print $1}')"
198 '';
199 env.CGO_ENABLED = 1;
200 };
201 });
202 apps = forAllSystems (system: let
203 pkgs = nixpkgsFor."${system}";
204 packages' = self.packages.${system};
205 air-watcher = name: arg:
206 pkgs.writeShellScriptBin "run"
207 ''
208 export PATH=${pkgs.go}/bin:$PATH
209 ${pkgs.air}/bin/air -c ./.air/${name}.toml \
210 -build.args_bin "${arg}"
211 '';
212 tailwind-watcher =
213 pkgs.writeShellScriptBin "run"
214 ''
215 ${pkgs.tailwindcss}/bin/tailwindcss --watch=always -i input.css -o ./appview/pages/static/tw.css
216 '';
217 in {
218 fmt = {
219 type = "app";
220 program = pkgs.lib.getExe packages'.treefmt-wrapper;
221 };
222 watch-appview = {
223 type = "app";
224 program = toString (pkgs.writeShellScript "watch-appview" ''
225 echo "copying static files to appview/pages/static..."
226 mkdir -p appview/pages/static
227 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership ${packages'.appview-static-files}/* appview/pages/static
228 ${air-watcher "appview" ""}/bin/run
229 '');
230 };
231 watch-knot = {
232 type = "app";
233 program = ''${air-watcher "knot" "server"}/bin/run'';
234 };
235 watch-spindle = {
236 type = "app";
237 program = ''${air-watcher "spindle" ""}/bin/run'';
238 };
239 watch-tailwind = {
240 type = "app";
241 program = ''${tailwind-watcher}/bin/run'';
242 };
243 vm = let
244 guestSystem =
245 if pkgs.stdenv.hostPlatform.isAarch64
246 then "aarch64-linux"
247 else "x86_64-linux";
248 in {
249 type = "app";
250 program =
251 (pkgs.writeShellApplication {
252 name = "launch-vm";
253 text = ''
254 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
255 cd "$rootDir"
256
257 mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
258
259 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
260 exec ${pkgs.lib.getExe
261 (import ./nix/vm.nix {
262 inherit nixpkgs self;
263 system = guestSystem;
264 hostSystem = system;
265 }).config.system.build.vm}
266 '';
267 })
268 + /bin/launch-vm;
269 };
270 gomod2nix = {
271 type = "app";
272 program = toString (pkgs.writeShellScript "gomod2nix" ''
273 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
274 '');
275 };
276 lexgen = {
277 type = "app";
278 program =
279 (pkgs.writeShellApplication {
280 name = "lexgen";
281 text = ''
282 if ! command -v lexgen > /dev/null; then
283 echo "error: must be executed from devshell"
284 exit 1
285 fi
286
287 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
288 cd "$rootDir"
289
290 rm -f api/tangled/*
291 lexgen --build-file lexicon-build-config.json lexicons
292 sed -i.bak 's/\tutil/\/\/\tutil/' api/tangled/*
293 # lexgen generates incomplete Marshaler/Unmarshaler for union types
294 find api/tangled/*.go -not -name "cbor_gen.go" -exec \
295 sed -i '/^func.*\(MarshalCBOR\|UnmarshalCBOR\)/,/^}/ s/^/\/\/ /' {} +
296 ${pkgs.gotools}/bin/goimports -w api/tangled/*
297 go run ./cmd/cborgen/
298 lexgen --build-file lexicon-build-config.json lexicons
299 rm api/tangled/*.bak
300 '';
301 })
302 + /bin/lexgen;
303 };
304 });
305
306 nixosModules.appview = {
307 lib,
308 pkgs,
309 ...
310 }: {
311 imports = [./nix/modules/appview.nix];
312
313 services.tangled.appview.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.appview;
314 };
315 nixosModules.knot = {
316 lib,
317 pkgs,
318 ...
319 }: {
320 imports = [./nix/modules/knot.nix];
321
322 services.tangled.knot.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot;
323 };
324 nixosModules.spindle = {
325 lib,
326 pkgs,
327 ...
328 }: {
329 imports = [./nix/modules/spindle.nix];
330
331 services.tangled.spindle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.spindle;
332 };
333 };
334}