lewis.moe
Monorepo for Tangled
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 gomod2nix = {
7 url = "github:nix-community/gomod2nix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 flake-compat = {
11 url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
12 flake = false;
13 };
14 indigo = {
15 url = "github:oppiliappan/indigo";
16 flake = false;
17 };
18 htmx-src = {
19 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
20 flake = false;
21 };
22 htmx-ws-src = {
23 # strange errors in consle that i can't really make out
24 # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
25 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
26 flake = false;
27 };
28 lucide-src = {
29 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
30 flake = false;
31 };
32 inter-fonts-src = {
33 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
34 flake = false;
35 };
36 actor-typeahead-src = {
37 url = "git+https://tangled.org/@jakelazaroff.com/actor-typeahead";
38 flake = false;
39 };
40 ibm-plex-mono-src = {
41 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
42 flake = false;
43 };
44 sqlite-lib-src = {
45 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
46 flake = false;
47 };
48 };
49
50 outputs = {
51 self,
52 nixpkgs,
53 gomod2nix,
54 indigo,
55 htmx-src,
56 htmx-ws-src,
57 lucide-src,
58 inter-fonts-src,
59 sqlite-lib-src,
60 ibm-plex-mono-src,
61 actor-typeahead-src,
62 ...
63 }: let
64 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
65 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
66 nixpkgsFor = forAllSystems (system: nixpkgs.legacyPackages.${system});
67
68 mkPackageSet = pkgs:
69 pkgs.lib.makeScope pkgs.newScope (self: {
70 src = let
71 fs = pkgs.lib.fileset;
72 in
73 fs.toSource {
74 root = ./.;
75 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
76 };
77 buildGoApplication =
78 (self.callPackage "${gomod2nix}/builder" {
79 gomod2nix = gomod2nix.legacyPackages.${pkgs.stdenv.hostPlatform.system}.gomod2nix;
80 }).buildGoApplication;
81 modules = ./nix/gomod2nix.toml;
82 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
83 inherit sqlite-lib-src;
84 };
85 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
86 goat = self.callPackage ./nix/pkgs/goat.nix {inherit indigo;};
87 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
88 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src actor-typeahead-src;
89 };
90 appview = self.callPackage ./nix/pkgs/appview.nix {};
91 docs = self.callPackage ./nix/pkgs/docs.nix {
92 inherit inter-fonts-src ibm-plex-mono-src lucide-src;
93 };
94 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
95 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
96 knot = self.callPackage ./nix/pkgs/knot.nix {};
97 dolly = self.callPackage ./nix/pkgs/dolly.nix {};
98 });
99 in {
100 overlays.default = final: prev: {
101 inherit (mkPackageSet final) lexgen goat sqlite-lib spindle knot-unwrapped knot appview docs dolly;
102 };
103
104 packages = forAllSystems (system: let
105 pkgs = nixpkgsFor.${system};
106 packages = mkPackageSet pkgs;
107 staticPackages = mkPackageSet pkgs.pkgsStatic;
108 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
109 in {
110 inherit
111 (packages)
112 appview
113 appview-static-files
114 lexgen
115 goat
116 spindle
117 knot
118 knot-unwrapped
119 sqlite-lib
120 docs
121 dolly
122 ;
123
124 pkgsStatic-appview = staticPackages.appview;
125 pkgsStatic-knot = staticPackages.knot;
126 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
127 pkgsStatic-spindle = staticPackages.spindle;
128 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
129 pkgsStatic-dolly = staticPackages.dolly;
130
131 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
132 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
133 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
134 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
135 pkgsCross-gnu64-pkgsStatic-dolly = crossPackages.dolly;
136
137 treefmt-wrapper = pkgs.treefmt.withConfig {
138 settings.formatter = {
139 alejandra = {
140 command = pkgs.lib.getExe pkgs.alejandra;
141 includes = ["*.nix"];
142 };
143
144 gofmt = {
145 command = pkgs.lib.getExe' pkgs.go "gofmt";
146 options = ["-w"];
147 includes = ["*.go"];
148 };
149
150 # prettier = let
151 # wrapper = pkgs.runCommandLocal "prettier-wrapper" {nativeBuildInputs = [pkgs.makeWrapper];} ''
152 # makeWrapper ${pkgs.prettier}/bin/prettier "$out" --add-flags "--plugin=${pkgs.prettier-plugin-go-template}/lib/node_modules/prettier-plugin-go-template/lib/index.js"
153 # '';
154 # in {
155 # command = wrapper;
156 # options = ["-w"];
157 # includes = ["*.html"];
158 # # causes Go template plugin errors: https://github.com/NiklasPor/prettier-plugin-go-template/issues/120
159 # excludes = ["appview/pages/templates/layouts/repobase.html" "appview/pages/templates/repo/tags.html"];
160 # };
161 };
162 };
163 });
164 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
165 devShells = forAllSystems (system: let
166 pkgs = nixpkgsFor.${system};
167 packages' = self.packages.${system};
168 staticShell = pkgs.mkShell.override {
169 stdenv = pkgs.pkgsStatic.stdenv;
170 };
171 in {
172 default = staticShell {
173 nativeBuildInputs = [
174 pkgs.go
175 pkgs.air
176 pkgs.gopls
177 pkgs.httpie
178 pkgs.litecli
179 pkgs.websocat
180 pkgs.tailwindcss
181 pkgs.nixos-shell
182 pkgs.redis
183 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
184 packages'.lexgen
185 packages'.treefmt-wrapper
186 ];
187 shellHook = ''
188 mkdir -p appview/pages/static
189 # no preserve is needed because watch-tailwind will want to be able to overwrite
190 cp -fr --no-preserve=ownership ${packages'.appview-static-files}/* appview/pages/static
191 export TANGLED_OAUTH_CLIENT_KID="$(date +%s)"
192 export TANGLED_OAUTH_CLIENT_SECRET="$(${packages'.goat}/bin/goat key generate -t P-256 | grep -A1 "Secret Key" | tail -n1 | awk '{print $1}')"
193 '';
194 env.CGO_ENABLED = 1;
195 };
196 });
197 apps = forAllSystems (system: let
198 pkgs = nixpkgsFor."${system}";
199 packages' = self.packages.${system};
200 air-watcher = name: arg:
201 pkgs.writeShellScriptBin "run"
202 ''
203 export PATH=${pkgs.go}/bin:$PATH
204 ${pkgs.air}/bin/air -c ./.air/${name}.toml \
205 -build.args_bin "${arg}"
206 '';
207 tailwind-watcher =
208 pkgs.writeShellScriptBin "run"
209 ''
210 ${pkgs.tailwindcss}/bin/tailwindcss --watch=always -i input.css -o ./appview/pages/static/tw.css
211 '';
212 in {
213 fmt = {
214 type = "app";
215 program = pkgs.lib.getExe packages'.treefmt-wrapper;
216 };
217 watch-appview = {
218 type = "app";
219 program = toString (pkgs.writeShellScript "watch-appview" ''
220 echo "copying static files to appview/pages/static..."
221 mkdir -p appview/pages/static
222 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership ${packages'.appview-static-files}/* appview/pages/static
223 ${air-watcher "appview" ""}/bin/run
224 '');
225 };
226 watch-knot = {
227 type = "app";
228 program = ''${air-watcher "knot" "server"}/bin/run'';
229 };
230 watch-spindle = {
231 type = "app";
232 program = ''${air-watcher "spindle" ""}/bin/run'';
233 };
234 watch-tailwind = {
235 type = "app";
236 program = ''${tailwind-watcher}/bin/run'';
237 };
238 vm = let
239 guestSystem =
240 if pkgs.stdenv.hostPlatform.isAarch64
241 then "aarch64-linux"
242 else "x86_64-linux";
243 in {
244 type = "app";
245 program =
246 (pkgs.writeShellApplication {
247 name = "launch-vm";
248 text = ''
249 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
250 cd "$rootDir"
251
252 mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
253
254 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
255 exec ${pkgs.lib.getExe
256 (import ./nix/vm.nix {
257 inherit nixpkgs self;
258 system = guestSystem;
259 hostSystem = system;
260 }).config.system.build.vm}
261 '';
262 })
263 + /bin/launch-vm;
264 };
265 gomod2nix = {
266 type = "app";
267 program = toString (pkgs.writeShellScript "gomod2nix" ''
268 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
269 '');
270 };
271 lexgen = {
272 type = "app";
273 program =
274 (pkgs.writeShellApplication {
275 name = "lexgen";
276 text = ''
277 if ! command -v lexgen > /dev/null; then
278 echo "error: must be executed from devshell"
279 exit 1
280 fi
281
282 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
283 cd "$rootDir"
284
285 rm -f api/tangled/*
286 lexgen --build-file lexicon-build-config.json lexicons
287 sed -i.bak 's/\tutil/\/\/\tutil/' api/tangled/*
288 # lexgen generates incomplete Marshaler/Unmarshaler for union types
289 find api/tangled/*.go -not -name "cbor_gen.go" -exec \
290 sed -i '/^func.*\(MarshalCBOR\|UnmarshalCBOR\)/,/^}/ s/^/\/\/ /' {} +
291 ${pkgs.gotools}/bin/goimports -w api/tangled/*
292 go run ./cmd/cborgen/
293 lexgen --build-file lexicon-build-config.json lexicons
294 rm api/tangled/*.bak
295 '';
296 })
297 + /bin/lexgen;
298 };
299 });
300
301 nixosModules.appview = {
302 lib,
303 pkgs,
304 ...
305 }: {
306 imports = [./nix/modules/appview.nix];
307
308 services.tangled.appview.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.appview;
309 };
310 nixosModules.knot = {
311 lib,
312 pkgs,
313 ...
314 }: {
315 imports = [./nix/modules/knot.nix];
316
317 services.tangled.knot.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot;
318 };
319 nixosModules.spindle = {
320 lib,
321 pkgs,
322 ...
323 }: {
324 imports = [./nix/modules/spindle.nix];
325
326 services.tangled.spindle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.spindle;
327 };
328 };
329}