ladas552.me
forked from
tangled.org/core
Monorepo for Tangled
boltless.me
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 gomod2nix = {
7 url = "github:nix-community/gomod2nix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 flake-compat = {
11 url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
12 flake = false;
13 };
14 indigo = {
15 url = "github:oppiliappan/indigo";
16 flake = false;
17 };
18 htmx-src = {
19 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
20 flake = false;
21 };
22 htmx-ws-src = {
23 # strange errors in consle that i can't really make out
24 # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
25 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
26 flake = false;
27 };
28 lucide-src = {
29 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
30 flake = false;
31 };
32 inter-fonts-src = {
33 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
34 flake = false;
35 };
36 actor-typeahead-src = {
37 url = "git+https://tangled.org/@jakelazaroff.com/actor-typeahead";
38 flake = false;
39 };
40 ibm-plex-mono-src = {
41 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
42 flake = false;
43 };
44 sqlite-lib-src = {
45 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
46 flake = false;
47 };
48 };
49
50 outputs = {
51 self,
52 nixpkgs,
53 gomod2nix,
54 indigo,
55 htmx-src,
56 htmx-ws-src,
57 lucide-src,
58 inter-fonts-src,
59 sqlite-lib-src,
60 ibm-plex-mono-src,
61 actor-typeahead-src,
62 ...
63 }: let
64 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
65 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
66 nixpkgsFor = forAllSystems (system: nixpkgs.legacyPackages.${system});
67
68 mkPackageSet = pkgs:
69 pkgs.lib.makeScope pkgs.newScope (self: {
70 src = let
71 fs = pkgs.lib.fileset;
72 in
73 fs.toSource {
74 root = ./.;
75 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
76 };
77 buildGoApplication =
78 (self.callPackage "${gomod2nix}/builder" {
79 gomod2nix = gomod2nix.legacyPackages.${pkgs.stdenv.hostPlatform.system}.gomod2nix;
80 }).buildGoApplication;
81 modules = ./nix/gomod2nix.toml;
82 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
83 inherit sqlite-lib-src;
84 };
85 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
86 goat = self.callPackage ./nix/pkgs/goat.nix {inherit indigo;};
87 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
88 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src actor-typeahead-src;
89 };
90 appview = self.callPackage ./nix/pkgs/appview.nix {};
91 docs = self.callPackage ./nix/pkgs/docs.nix {
92 inherit inter-fonts-src ibm-plex-mono-src lucide-src;
93 };
94 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
95 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
96 knot = self.callPackage ./nix/pkgs/knot.nix {};
97 dolly = self.callPackage ./nix/pkgs/dolly.nix {};
98 did-method-plc = self.callPackage ./nix/pkgs/did-method-plc.nix {};
99 bluesky-jetstream = self.callPackage ./nix/pkgs/bluesky-jetstream.nix {};
100 bluesky-relay = self.callPackage ./nix/pkgs/bluesky-relay.nix {};
101 tap = self.callPackage ./nix/pkgs/tap.nix {};
102 });
103 in {
104 overlays.default = final: prev: {
105 inherit (mkPackageSet final) lexgen goat sqlite-lib spindle knot-unwrapped knot appview docs dolly did-method-plc bluesky-jetstream bluesky-relay tap;
106 };
107
108 packages = forAllSystems (system: let
109 pkgs = nixpkgsFor.${system};
110 packages = mkPackageSet pkgs;
111 staticPackages = mkPackageSet pkgs.pkgsStatic;
112 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
113 in {
114 inherit
115 (packages)
116 appview
117 appview-static-files
118 lexgen
119 goat
120 spindle
121 knot
122 knot-unwrapped
123 sqlite-lib
124 docs
125 dolly
126 did-method-plc
127 bluesky-jetstream
128 bluesky-relay
129 tap
130 ;
131
132 pkgsStatic-appview = staticPackages.appview;
133 pkgsStatic-knot = staticPackages.knot;
134 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
135 pkgsStatic-spindle = staticPackages.spindle;
136 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
137 pkgsStatic-dolly = staticPackages.dolly;
138
139 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
140 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
141 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
142 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
143 pkgsCross-gnu64-pkgsStatic-dolly = crossPackages.dolly;
144
145 treefmt-wrapper = pkgs.treefmt.withConfig {
146 settings.formatter = {
147 alejandra = {
148 command = pkgs.lib.getExe pkgs.alejandra;
149 includes = ["*.nix"];
150 };
151
152 gofmt = {
153 command = pkgs.lib.getExe' pkgs.go "gofmt";
154 options = ["-w"];
155 includes = ["*.go"];
156 };
157
158 # prettier = let
159 # wrapper = pkgs.runCommandLocal "prettier-wrapper" {nativeBuildInputs = [pkgs.makeWrapper];} ''
160 # makeWrapper ${pkgs.prettier}/bin/prettier "$out" --add-flags "--plugin=${pkgs.prettier-plugin-go-template}/lib/node_modules/prettier-plugin-go-template/lib/index.js"
161 # '';
162 # in {
163 # command = wrapper;
164 # options = ["-w"];
165 # includes = ["*.html"];
166 # # causes Go template plugin errors: https://github.com/NiklasPor/prettier-plugin-go-template/issues/120
167 # excludes = ["appview/pages/templates/layouts/repobase.html" "appview/pages/templates/repo/tags.html"];
168 # };
169 };
170 };
171 });
172 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
173 devShells = forAllSystems (system: let
174 pkgs = nixpkgsFor.${system};
175 packages' = self.packages.${system};
176 staticShell = pkgs.mkShell.override {
177 stdenv = pkgs.pkgsStatic.stdenv;
178 };
179 in {
180 default = staticShell {
181 nativeBuildInputs = [
182 pkgs.go
183 pkgs.air
184 pkgs.gopls
185 pkgs.httpie
186 pkgs.litecli
187 pkgs.websocat
188 pkgs.tailwindcss
189 pkgs.nixos-shell
190 pkgs.redis
191 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
192 packages'.lexgen
193 packages'.treefmt-wrapper
194 packages'.tap
195 ];
196 shellHook = ''
197 mkdir -p appview/pages/static
198 # no preserve is needed because watch-tailwind will want to be able to overwrite
199 cp -fr --no-preserve=ownership ${packages'.appview-static-files}/* appview/pages/static
200 export TANGLED_OAUTH_CLIENT_KID="$(date +%s)"
201 export TANGLED_OAUTH_CLIENT_SECRET="$(${packages'.goat}/bin/goat key generate -t P-256 | grep -A1 "Secret Key" | tail -n1 | awk '{print $1}')"
202 '';
203 env.CGO_ENABLED = 1;
204 };
205 });
206 apps = forAllSystems (system: let
207 pkgs = nixpkgsFor."${system}";
208 packages' = self.packages.${system};
209 air-watcher = name: arg:
210 pkgs.writeShellScriptBin "run"
211 ''
212 export PATH=${pkgs.go}/bin:$PATH
213 ${pkgs.air}/bin/air -c ./.air/${name}.toml \
214 -build.args_bin "${arg}"
215 '';
216 tailwind-watcher =
217 pkgs.writeShellScriptBin "run"
218 ''
219 ${pkgs.tailwindcss}/bin/tailwindcss --watch=always -i input.css -o ./appview/pages/static/tw.css
220 '';
221 in {
222 fmt = {
223 type = "app";
224 program = pkgs.lib.getExe packages'.treefmt-wrapper;
225 };
226 watch-appview = {
227 type = "app";
228 program = toString (pkgs.writeShellScript "watch-appview" ''
229 echo "copying static files to appview/pages/static..."
230 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership ${packages'.appview-static-files}/* appview/pages/static
231 ${air-watcher "appview" ""}/bin/run
232 '');
233 };
234 watch-knot = {
235 type = "app";
236 program = ''${air-watcher "knot" "server"}/bin/run'';
237 };
238 watch-spindle = {
239 type = "app";
240 program = ''${air-watcher "spindle" ""}/bin/run'';
241 };
242 watch-tailwind = {
243 type = "app";
244 program = ''${tailwind-watcher}/bin/run'';
245 };
246 vm = let
247 guestSystem =
248 if pkgs.stdenv.hostPlatform.isAarch64
249 then "aarch64-linux"
250 else "x86_64-linux";
251 in {
252 type = "app";
253 program =
254 (pkgs.writeShellApplication {
255 name = "launch-vm";
256 text = ''
257 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
258 cd "$rootDir"
259
260 mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
261
262 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
263 exec ${pkgs.lib.getExe
264 (import ./nix/vm.nix {
265 inherit nixpkgs self;
266 system = guestSystem;
267 hostSystem = system;
268 }).config.system.build.vm}
269 '';
270 })
271 + /bin/launch-vm;
272 };
273 gomod2nix = {
274 type = "app";
275 program = toString (pkgs.writeShellScript "gomod2nix" ''
276 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
277 '');
278 };
279 lexgen = {
280 type = "app";
281 program =
282 (pkgs.writeShellApplication {
283 name = "lexgen";
284 text = ''
285 if ! command -v lexgen > /dev/null; then
286 echo "error: must be executed from devshell"
287 exit 1
288 fi
289
290 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
291 cd "$rootDir"
292
293 rm -f api/tangled/*
294 lexgen --build-file lexicon-build-config.json lexicons
295 sed -i.bak 's/\tutil/\/\/\tutil/' api/tangled/*
296 # lexgen generates incomplete Marshaler/Unmarshaler for union types
297 find api/tangled/*.go -not -name "cbor_gen.go" -exec \
298 sed -i '/^func.*\(MarshalCBOR\|UnmarshalCBOR\)/,/^}/ s/^/\/\/ /' {} +
299 ${pkgs.gotools}/bin/goimports -w api/tangled/*
300 go run ./cmd/cborgen/
301 lexgen --build-file lexicon-build-config.json lexicons
302 rm api/tangled/*.bak
303 '';
304 })
305 + /bin/lexgen;
306 };
307 });
308
309 nixosModules.appview = {
310 lib,
311 pkgs,
312 ...
313 }: {
314 imports = [./nix/modules/appview.nix];
315
316 services.tangled.appview.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.appview;
317 };
318 nixosModules.knot = {
319 lib,
320 pkgs,
321 ...
322 }: {
323 imports = [./nix/modules/knot.nix];
324
325 services.tangled.knot.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot;
326 };
327 nixosModules.spindle = {
328 lib,
329 pkgs,
330 ...
331 }: {
332 imports = [./nix/modules/spindle.nix];
333
334 services.tangled.spindle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.spindle;
335 services.tangled.spindle.tap-package = lib.mkDefault self.packages.${pkgs.system}.tap;
336 };
337 nixosModules.did-method-plc = {
338 lib,
339 pkgs,
340 ...
341 }: {
342 imports = [./nix/modules/did-method-plc.nix];
343 services.did-method-plc.package = lib.mkDefault self.packages.${pkgs.system}.did-method-plc;
344 };
345 nixosModules.bluesky-relay = {
346 lib,
347 pkgs,
348 ...
349 }: {
350 imports = [./nix/modules/bluesky-relay.nix];
351 services.bluesky-relay.package = lib.mkDefault self.packages.${pkgs.system}.bluesky-relay;
352 };
353 nixosModules.bluesky-jetstream = {
354 lib,
355 pkgs,
356 ...
357 }: {
358 imports = [./nix/modules/bluesky-jetstream.nix];
359 services.bluesky-jetstream.package = lib.mkDefault self.packages.${pkgs.system}.bluesky-jetstream;
360 };
361 };
362}