open Space_wire

let encode codec v =
  let ws = Wire.Codec.wire_size codec in
  let buf = Bytes.create ws in
  Wire.Codec.encode codec v buf 0;
  Bytes.unsafe_to_string buf

let decode codec s = Wire.Codec.decode codec (Bytes.of_string s) 0

let test_frame_roundtrip () =
  let frame = Msg.v TM ~apid:0x42 "hello world" in
  let encoded = encode Msg.codec frame in
  Alcotest.(check int) "frame size" 256 (String.length encoded);
  let decoded = decode Msg.codec encoded in
  Alcotest.(check bool) "roundtrip" true (Msg.equal frame decoded)

let test_frame_header_layout () =
  let frame = Msg.v TC ~apid:0x123 "test" in
  let encoded = encode Msg.codec frame in
  (* version=0x01 at offset 0 *)
  Alcotest.(check int) "version" 0x01 (Char.code encoded.[0]);
  (* type=0x01 (TC) at offset 1 *)
  Alcotest.(check int) "type" 0x01 (Char.code encoded.[1]);
  (* apid=0x0123 big-endian at offset 2-3 *)
  Alcotest.(check int) "apid high" 0x01 (Char.code encoded.[2]);
  Alcotest.(check int) "apid low" 0x23 (Char.code encoded.[3]);
  (* payload_length=4 at offset 4-5 *)
  Alcotest.(check int) "pay_len high" 0x00 (Char.code encoded.[4]);
  Alcotest.(check int) "pay_len low" 0x04 (Char.code encoded.[5]);
  (* reserved=0 at offset 6-7 *)
  Alcotest.(check int) "reserved high" 0x00 (Char.code encoded.[6]);
  Alcotest.(check int) "reserved low" 0x00 (Char.code encoded.[7]);
  (* payload starts at offset 8 *)
  Alcotest.(check char) "payload[0]" 't' encoded.[8]

let test_frame_all_types () =
  let types =
    Msg.[ TM; TC; EVR; PRM_GET; PRM_SET; PRM_RSP; DP; HEALTH; LOG; ERROR ]
  in
  List.iter
    (fun typ ->
      let frame = Msg.v typ ~apid:1 "" in
      let encoded = encode Msg.codec frame in
      let decoded = decode Msg.codec encoded in
      let typ_int = Msg.kind_to_int typ in
      Alcotest.(check int)
        (Fmt.str "type %a" Msg.pp_kind typ)
        typ_int decoded.msg_type)
    types

let test_frame_payload_bytes () =
  let frame = Msg.v TM ~apid:1 "abc" in
  let encoded = encode Msg.codec frame in
  let decoded = decode Msg.codec encoded in
  Alcotest.(check string) "payload_bytes" "abc" (Msg.payload_bytes decoded)

let test_frame_max_payload () =
  let big = String.make 300 'x' in
  let frame = Msg.v TM ~apid:1 big in
  Alcotest.(check int) "payload_length capped" 248 frame.payload_length

let suite =
  ( "msg",
    [
      Alcotest.test_case "roundtrip" `Quick test_frame_roundtrip;
      Alcotest.test_case "header layout" `Quick test_frame_header_layout;
      Alcotest.test_case "all types" `Quick test_frame_all_types;
      Alcotest.test_case "payload_bytes" `Quick test_frame_payload_bytes;
      Alcotest.test_case "max payload" `Quick test_frame_max_payload;
    ] )