{
  inputs,
  lib,
  self,
  ...
}:
{
  flake = {
    homeConfigurations = { };
    nixosConfigurations =
      (name: {
        ${name} = inputs.nixpkgs.lib.nixosSystem {
          modules = [
            # keep-sorted start block=yes prefix_order=inputs,self,./,{
            inputs.disko.nixosModules.disko
            inputs.home-manager.nixosModules.home-manager
            inputs.sops-nix.nixosModules.sops
            inputs.stylix.nixosModules.stylix
            self.nixosModules.default
            self.nixosModules.homelab
            ./nixos/${name}
            {
              home-manager = {
                sharedModules = [
                  inputs.sops-nix.homeManagerModules.sops
                  inputs.vicinae.homeManagerModules.default
                  inputs.zen-browser.homeModules.beta
                  self.homeModules.default
                ];
                users.da157 = {
                  imports = [ self.homeModules.da157 ];
                  l.secrets.enable = true;
                };
              };
            }
            # keep-sorted end
          ];
          specialArgs = {
            inherit
              inputs
              lib
              name
              self
              ;
          };
        };
      })
      |> lib.forEach (
        builtins.readDir ./nixos
        |> lib.mapAttrsToList (name: kind: lib.optional (kind == "directory") name)
        |> builtins.concatLists
      )
      |> lib.mergeAttrsList;
  };
}